Here are some example configuration files for DomTool, our distributed configuration management system.

[[TableOfContents()]]

= Domains =

== The Model T ==

If you just want to declare your domain with a `www.yourdomain` virtual host serving out of `~/public_html/` and all mail forwarded to your mailbox, use:
{{{dom "yourdomain" with
end;}}}

== Upgraded Model T ==

If you like everything `dom` gives you but want to add additional configuration, include it between `with`..`end`. For instance, to add an extra web virtual host `other`:
{{{dom "yourdomain" with
  web "other" with
    (* More configuration could go here *)
  end;
end;}}}

== The Do-It-Yourself ==

The lowest-level way of configuring a domain is the `domain` directive, which does nothing but set up basic DNS parameters and provide a space for including further directives:
{{{domain "yourdomain" with
  (* Your directives here *)
end;}}}

= DNS =

Here's a tour through the available DNS features.

{{{domain "yourdomain" with
  nameserver "ns.hcoop.net";
  nameserver "ns2.hcoop.net";
  (* Specify two DNS servers that are authoritative for yourdomain *)

  dnsIP "host" "1.2.3.4";
  (* Add a mapping from host.yourdomain to IP address 1.2.3.4 *)

  dnsMail 23 "mail.yourdomain";
  (* Register mail.yourdomain as an SMTP handler for yourdomain, with priority 23 *)

  dnsAlias "hcoop" "hcoop.net";
  (* Add an alias such that hcoop.yourdomain resolves to the same thing as hcoop.net *)

  dnsIP "dynamic" "5.6.7.8" where
    TTL = 100
  end;
  (* Add an IP mapping with an abnormally low time-to-live of 100 *)
end;}}}

= Mail =

{{{domain "yourdomain" with
  handleMail;
  (* HCoop should provide relaying for yourdomain *)

  emailAlias "user1" "user1@gmail.com";
  (* Forward mail from user1@yourdomain to user1@gmail.com *)

  emailAlias "user2" "me";
  (* Forward mail from user2@yourdomain to HCoop user me *)

  aliasMulti "pals" ["pal1@yahoo.com", "pal2@prodigy.com", "pal3"];
  (* Forward mail from pals@yorudomain to pal1@yahoo.com, pal2@prodigy.com, and HCoop user pal3 *)

  aliasDrop "spamtrap";
  (* Silently drop all mail to spamtrap@yourdomain *)

  defaultAlias "me";
  (* Send all yourdomain mail that doesn't match some local user or other special rule to user me *)

  catchAllAlias "me";
  (* Send all yourdomain mail, period, to user me *)
end;}}}