This page contains a number of working examples of DomTool configuration.

TableOfContents

MichaelOlson

Here is MichaelOlson's annotated DomTool configuration.

domain "mwolson.org" with
  (* DNS settings *)
  nameserver "ns1.hcoop.net";
  nameserver "ns3.hcoop.net";
  dnsDefault "69.90.123.68";
  dnsIP "www" "69.90.123.68";
  dnsIP "blog" "69.90.123.68";
  dnsIP "hariken" "66.253.212.116";  (* my home computer *)
  dnsIP "mail" "69.90.123.67";
  dnsMail 10 "mail.mwolson.org";

  (* email *)
  handleMail;
  emailAlias "me" "mwolson";
  emailAlias "me.purdue" "mwolson";
  emailAlias "me.vending" "mwolson";
  emailAlias "mwolson" "mwolson";
  emailAlias "hostmaster" "mwolson";
  emailAlias "news" "mwolson";
  emailAlias "webmaster" "mwolson";

  (* Default webspace *)
  vhost "www" where
    DocumentRoot = (home "public_html");
  with
    addDefaultCharset "utf-8";
    serverAliasDefault;

    (* Change www.mwolson.org to mwolson.org *)
    rewriteCond "%{HTTP_HOST}" "^www\.mwolson\.org$" [cond_nocase];
    rewriteRule "^(.*)$" "http://mwolson.org$1" [redirectWith redir301,last];

    scriptAlias "/cgi-bin/" (home "cgi-bin/");
    rewriteRule "^/$" "http://mwolson.org/web/WelcomePage.html" [last];
    rewriteRule "^/blog/projects(.*)"
                "http://blog.mwolson.org/tech/projects$1"
                [redirectWith redir301,last];
    rewriteRule "^/blog([^.].*)" "http://blog.mwolson.org$1"
                [redirectWith redir301,last];
    rewriteRule "^/cs158" "http://mwolson.org/classes/cs158/index.html" [];
    rewriteRule "^/favicon\.ico$"
                "http://mwolson.org/static/logos/favicon.ico" [];
    rewriteRule "^/static/albums/(.*)"
                "http://mwolson.risnerolson.org/albums/$1" [];
  end;

  (* Example of serving page to deleuze, should we ever decide to *)
  (* allow that *)

(*   vhost "git" where *)
(*     WebNodes = ["deleuze"]; *)
(*   with ... *)
(*   end; *)

  (* Blog *)
  vhost "blog" where
    DocumentRoot = (home "public_html/blog");
  with
    addDefaultCharset "utf-8";
    alias "/favicon.ico" (home "public_html/static/logos/favicon.ico");
    alias "/comments.js" (home "public_html/comments.js");
    rewriteRule "^/projects(.*)" "http://blog.mwolson.org/tech/projects$1" [];
    scriptAlias "/" (home "cgi-bin/pyblosxom/pyblosxom.cgi/");
  end;

  (* DAV access *)
  vhost "dav" with
    rewriteRule "^(.*)$" "https://dav.mwolson.org$1" [redirect];
  end;

  vhost "dav" where
    DocumentRoot = (home "dav");
    (* NOTE: The following is a temporary measure.  It probably *)
    (* won't work for you.  See MemberManual/ServingWebsites. *)
    SSL = use_cert "/etc/apache2/ssl/apache.pem";
  with
    addDefaultCharset "utf-8";

    location "/" with
      davFilesystem;
    end;
  end;

end;